home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Aminet 21
/
Aminet 21 (1997)(GTI - Schatztruhe)[!][Oct 1997].iso
/
Aminet
/
pix
/
trace
/
Petanque.lha
/
petanque
/
petanque.pov
< prev
next >
Wrap
Text File
|
1997-08-05
|
3KB
|
138 lines
/* Partie de pétangque té cong ! */
#include "colors.inc"
#include "textures.inc"
#version 3.0
#declare Rainure1 =
union {
torus { 0.05*sqrt(2), 0.005 translate 0.05*sqrt(2)*y }
torus { 0.05*sqrt(2), 0.005 translate -0.05*sqrt(2)*y }
}
#declare Boule_Amie =
object {
difference {
sphere { <0, 0, 0>, 0.1 }
Rainure1
}
texture {Polished_Chrome}
}
#declare Boule_Ennemie =
object {
difference {
sphere { <0, 0, 0>, 0.1 }
Rainure1
object { Rainure1 rotate 90*z }
}
texture {Polished_Chrome}
}
#declare Cochonnet =
object {
sphere { <0, 0, 0>, 0.03 }
texture {
pigment {
color rgb <1, 0.4, 0.5>
}
normal { bumps 0.7 scale .001 }
}
}
sphere { <0, 0, 0>, 1000 inverse
texture {
pigment { color rgb <.35, .3, 1> }
finish { ambient 1 diffuse 0 }
}
texture {
pigment {
bozo
turbulence 0.6
color_map {
[0 color rgbf <0.5, 0.5, 0.5, 0.2>]
[0.4 color rgbf <0.8, 0.8, 0.8, 0.4>]
[0.55 color rgbf <1, 1, 1, 1> ]
[1 color rgbf <1, 1, 1, 1> ]
}
scale <200, 50, 200>
}
finish { ambient 1 diffuse 0 }
}
}
object { Boule_Amie rotate <25, 30, 15> translate 0.1*y }
object { Boule_Ennemie rotate <75, 11, 12> translate 0.1*y+1.5*x+0.1*z }
object { Boule_Ennemie rotate <15, 23, 200> translate 0.1*y+.8*x+0.3*z }
object { Cochonnet translate 0.035*y+0.4*x+0.1*z }
#declare r_init=<50, 20, 10>
#declare r_per_frame=<12, 13, 40>
#declare p_init=.1*y+<-1, 0.6, 0.2>
#declare p_per_frame=0.05*<0.95, -0.3, 0>
object { Boule_Amie
rotate r_init+(r_per_frame)*clock
translate p_init+(p_per_frame)*clock
}
object { // playground
plane { y, 0 }
texture {
pigment { color rgb <16, 115, 8>/256 }
normal { bumps 0.4 }
}
texture {
pigment {
image_map {
gif "Terrain.gif"
map_type 0
interpolate 2
once
}
rotate 90*x
scale 10
translate -5*x-5*z
}
normal { bumps 0.4 scale 0.8 }
}
}
union {
object { // Panneau
box { <-0.7, -0.4, 0>, <0.7, 0.4, 0.15> }
texture { Tan_Wood rotate <10, 70, 00> scale 2}
texture {
pigment {
image_map {
gif "Pancarte.gif"
map_type 0
interpolate 2
filter 0 1
filter 1 0.875
filter 2 0.75
filter 3 0.625
filter 4 0.5
filter 5 0.375
filter 6 0.25
filter 7 0.125
}
scale <1.4, 0.8, 1>
translate <-0.7, -0.4, 0>
}
}
}
object {
cylinder { <0, 0.2, 0.25>, <0, -1, 0.25>, 0.1 }
texture { Tan_Wood }
}
rotate <5, 0, 6>
translate 1*y+4*z
}
light_source { 0.2*<-1, 2, -3> color rgb <1, 1, 1>*2 }
light_source { 0.2*<2, 1.5, -2> color rgb <1, 1, 1>*2 }
light_source { <6, 3, 4> color rgb <2, 2, 2> }
camera { location 1*x-1.5*z+0.5*y look_at <0.5, 0, 1> }
//camera { location -4*z look_at <0, 0, 0> }